Mac shortcuts on windows

I’ve been using macOS as my main driver for the past 10 years or so. Last month, I bought a PC.

Since I now switch between macOS and Windows daily — mac for work and Windows for personal — I wanted to find a way to synchronize my workflow, specifically:

• applications
• keyboard shortcuts (hotkeys)

Overview

This guide assumes you prefer the keyboard shortcuts and applications on macOS and you want them to be similar on Windows 10.

Applications

Here are a list of applications on macOS and their equivalent on Windows. You’ll need to install the Windwos ones if you don’t already have them:

• Rocket -> Windows Emoji Picker (built-in with Windows 10)
  • used to quickly type emojis
• Alfred -> PowerToys Run
  • used to quickly open apps, or change computer state (sleep, restart, shutdown)
• macOS Screenshot Tool -> Windows Snipping Tool (built-in)
  • used to take screenshots
• Clippy -> Windows Clipboard
  • manages your clipboard history
• N/A -> PowerToys
  • comes with a Keyboard Manager and many other tools
• N/A -> Easy Window Switcher
  • adds a keyboard shortcut to switch between windows of the same application on Windows

Keyboard Shortcuts

This is the main component to syncing your workflows. I found that after remapping these keys and shortcuts, it became 10x more seamless switching between operating systems.

1. Open PowerToys
2. Go to Keyboard Manager
3. Add the following Keys

• Caps Lock to Esc

  This is for vim’ing.

• Esc to Caps Lock

  I don’t use the actual Esc key so map back to Caps Lock in case we need it.

• Ctrl to Alt

  Switch these two to be more like macOS

• Alt to Ctrl

  Same as above

1. Add the following Shortcuts

• CtrlTab to AltTab — Switch Application Windows similar to macOS
• CtrlSpace to AltSpace — Launches the shortcut menu (like Spotlight)
• CtrlLeft to Home — Moves cursor to start of line
• CtrlRight to End — Moves cursor to end of line
• CtrlQ to AltF4 — Quit applications like on macOS
• Ctrl` to Alt` — Toggle between windows of same application
• CtrlShift4 to WinShiftS — Take screenshots like on macOS
• CtrlShiftV to WinV — Launch Clipboard history like with Clippy on macOS
• WinShiftLeft to CtrlShiftLeft — Select word by word moving left
• WinShiftRight to CtrlShiftRight — Select word by word moving right.
• WinCtrlLeft to CtrlShiftTab — Move to the previous tab
• WinCtrlRight to CtrlTab — Move to the next tab

Additional Notes

There are some limitations to this. For instance, connecting to bluetooth devices on macOS is only two clicks vs four clicks on Windows. I also couldn’t make the Windows Emoji Picker exactly like Rocket.

Sometimes the keyboard manager in PowerToys doesn’t work and I have to restart my PC.

Other times, putting my PC to sleep and waking it back up, applications randomly stop working.

PowerToys doesn’t let you export your Keyboard Manager settings so there’s no easy way to back them up besides taking screenshots.

You may need to restart some apps for the keyboard shortcuts to take effect.

You may need to remap some shortcuts on applications like VS Code or Obsidian.

@migueldeicaza on June 1st, 2021

Apple’s real lock-in is not the AppStore, it is ⌘C, ⌘V and ⌘X working everywhere — that’s why I can never go back to Linux or use Windows.

1.5k likes · Go to Twitter thread

; Sets up macOS-like keybindings on Windows via AutoHotkey.
;
; Last updated on 2021-07-14.

#SingleInstance force
#NoEnv
#Persistent
#InstallKeybdHook

Menu, Tray, Standard

GroupAdd, terminals, ahk_exe powershell.exe
GroupAdd, terminals, ahk_exe WindowsTerminal.exe
GroupAdd, terminals, ahk_exe Cmd.exe
GroupAdd, terminals, ahk_exe mstsc.exe ; Remote desktop.

GroupAdd, posix, ahk_exe powershell.exe
GroupAdd, posix, ahk_exe WindowsTerminal.exe
GroupAdd, posix, ahk_exe Cmd.exe
GroupAdd, posix, ahk_exe gvim.exe
GroupAdd, posix, ahk_exe mstsc.exe ; Remote desktop.

GroupAdd, vscode, ahk_exe VSCodium.exe
GroupAdd, vscode, ahk_exe Code.exe

; Emergency clear.
*PrintScreen::
Reload
Goto ReleaseModifiers
return

; CHEATSHEET
; # Win    ! Alt    ^ Ctrl    + Shift
;
; These modifiers work *after* remapping the modifiers.
; It doesn't matter where the keys are remapped; order is irrelevant.

;$AppsKey::RCtrl  ; Surface Laptop.
$AppsKey::RWin  ; Sculpt keyboard.

; Program launchers.
$#e::Run explorer
$#n::Run notepad
$#t::Run wt

; Window manipulation.
$!q::Send !{F4}

; Workspace movement.
$^Left::Send ^#{Left}
$^Right::Send ^#{Right}

; Screenshots.
;$!+3::Send {PrintScreen}
;$!+4::Send #+{S}

; Special characters.
$^+c::Send {�}
$^+n::Send {�}
$!-::Send {�}
$!+-::Send {�}

; Hide all instances of active program.
!h::
WinGetClass, class, A
SetTitleMatchMode, 2
WinGet, AllWindows, List
loop %AllWindows% {
    WinGetClass, WinClass, % "ahk_id " AllWindows%A_Index%
    if(InStr(WinClass,class)){
        WinMinimize, % "ahk_id " AllWindows%A_Index%
    }
}
return

; Cycle between same-app windows.
!`::
WinGet, ActiveProcess, ProcessName, A
WinGet, OpenWindowsAmount, Count, ahk_exe %ActiveProcess%
if (OpenWindowsAmount > 1) {
    WinGetTitle, FullTitle, A
    AppTitle := SubStr(FullTitle, InStr(FullTitle, " ", false, -1) + 1)

    SetTitleMatchMode, 2
    WinGet, WindowsWithSameTitleList, List, %AppTitle%

    if (WindowsWithSameTitleList > 1) {
        WinActivate, % "ahk_id " WindowsWithSameTitleList%WindowsWithSameTitleList%
    }
}
return


; Lock screen and turn off monitor.
$!^q::
    Sleep, 200
    DllCall("LockWorkStation")
    Sleep, 200
    SendMessage,0x112,0xF170,2,,Program Manager
    return

#IfWinNotActive ahk_group posix
    $!a::Send ^a ; Select all.
    $!f::Send ^f ; Find.
    $!l::Send ^l ; Location bar.
    $!r::Send {F5} ; Refresh.
    $!z::Send ^z ; Undo.
    $!+z::Send ^y ; Redo.
    $^!Space::Send #; ; Emoji selector.

    ; File manipulation.
    $!o::Send ^o
    $!s::Send ^s

    ; Line edits.
    $^k::SendInput +{End}{Delete}
    $^o::SendInput {Enter}{Up}
    $!/::Send ^/ ; Comment line.

    ; Word edits.
    $#Backspace::Send ^{Backspace}
    $!Backspace::Send ^{Backspace}

    ; Cursor movement.
    $^a::Send {Home}
    $^e::Send {End}
    $^p::SendInput {Up}
    $^n::SendInput {Down}
    $^b::SendInput {Left}
    $^f::SendInput {Right}
    $#b::SendInput ^{Left}
    $#f::SendInput ^{Right}

    $!Left::Send {Home}
    $!Right::Send {End}
    $!+Left::Send +{Home}
    $!+Right::Send +{End}

    ; Formatting.
    $!b::Send ^b ; Bold.
    $!i::Send ^i ; Italic.
    $!u::Send ^u ; Underline.
    $!k::Send ^k ; Insert link.
#If

#IfWinActive ahk_group vscode
    $!+p::Send ^+p ; File bar.
    $!p::Send ^p ; File bar.
    $!,::Send ^, ; Settings.
#If

#IfWinNotActive ahk_group terminals
    ; Clipboard.
    $!c::Send ^c
    $!v::Send ^v
    $!+v::Send ^+v
    $!x::Send ^x

    ; Tabs.
    $!w::Send ^w
    $!n::Send ^n
    $!+n::Send ^+n
    $!t::Send ^t
    $!+t::Send ^+t
    $!+{::send ^{PgUp}
    $!+}::send ^{PgDn}
    $!0::Send ^0
    $!1::Send ^1
    $!2::Send ^2
    $!3::Send ^3
    $!4::Send ^4
    $!5::Send ^5
    $!6::Send ^6
    $!7::Send ^7
    $!8::Send ^8
    $!9::Send ^9

    $^d::SendInput {Delete} ; Delete character.
    $!,::Send ^, ; Settings.
#If
#IfWinActive ahk_group terminals
    ; Clipboard.
    $!c::Send ^+c
    $!v::Send ^+v

    ; Tabs.
    $!w::Send ^+w
    $!n::Send ^+n
    $!t::Send ^+t
    $!+{::send ^+{Tab}
    $!+}::send ^{Tab}
    $!0::Send ^!0
    $!1::Send ^!1
    $!2::Send ^!2
    $!3::Send ^!3
    $!4::Send ^!4
    $!5::Send ^!5
    $!6::Send ^!6
    $!7::Send ^!7
    $!8::Send ^!8
    $!9::Send ^!9
    $!+0::Send ^+0
    $!+1::Send ^+1
    $!+2::Send ^+2
    $!+3::Send ^+3
    $!+4::Send ^+4
    $!+5::Send ^+5
    $!+6::Send ^+6
    $!+7::Send ^+7
    $!+8::Send ^+8
    $!+9::Send ^+9

    $!,::Send ^, ; Settings.
#If

ReleaseModifiers:
Send {RCtrl up}
Send {LCtrl up}
Send {RAlt up}
Send {LAlt up}
Send {RWin up}
Send {LWin up}
Send {RShift up}
Send {LShift up}
return

$startup = "$Home\AppData\Roaming\Microsoft\Windows\Start Menu\Programs\Startup"
if (!(Test-Path "$startup")) {
    mkdir -Path "$startup"
}
$WshShell = New-Object -comObject WScript.Shell
$Shortcut = $WshShell.CreateShortcut("$startup\macos.ahk.lnk")
$Shortcut.TargetPath = "$Home\config\macos.ahk"
$Shortcut.Save()